Home > Visual Basic > Beberapa alternatif menampilkan file gambar via jaringan

Beberapa alternatif menampilkan file gambar via jaringan

September 20, 2010 Leave a comment Go to comments

Di beberapa aplikasi seperti sistem informasi sekolah mengharuskan kita untuk menampilkan gambar pada form-form tertentu seperti Logo Sekolah, TTD Kepala Sekolah dan Foto Guru/Siswa.

Adapun komponen standar yang biasa digunakan untuk menampilkan gambar di Visual Basic adalah komponen Image dan PictureBox. Kodenya pun sangat sederhana bisa kita lihat seperti dibawah ini :

Private Sub cmdLoadFoto_Click()
    picSiswa.Picture = LoadPicture("Lokasi_file_gambar\file_foto.jpg")
End Sub

dan berdasarkan kode sederhana diatas akan kita kembangkan kodenya agar bisa menampilkan gambar via jaringan :

1. Menyimpan gambar langsung di database

Cara ini sangat efektif sekali untuk menyimpan gambar yang ukurannya kecil dan tidak terlalu banyak, misal logo sekolah atau TTD kepala sekolah. Jadi hilangkan pikiran2x kotor :D untuk menyimpan foto-foto guru/siswa langsung didatabase karena hal ini akan mempengaruhi kinerja database, walaupun jaman sekarang hardisk2xnya udah gede tapi tetap saja menyimpan gambar secara langsung (dalam jumlah banyak) kurang baik untuk kesehatan database :D.

Bagaimana cara menyimpan dan menampilkan gambar dari database sudah saya bahas tuntas diSINI.

2. Share folder

Nah klo file gambarnya lumayan banyak seperti foto guru/siswa, cara ini mungkin bisa dicoba. Jadi foto guru/siswanya dikumpulkan di dalam 1 folder kemudian di share, selanjutnya dari aplikasi tinggal panggil seperti berikut :

Private Sub cmdLoadFoto_Click()
    picSiswa.Picture = LoadPicture("\\ip_server\folder_yg_dishare\file_foto.jpg")

    'atau dengan menyebutkan langsung nama komputer
    picSiswa.Picture = LoadPicture("\\nama_komputer_server\folder_yg_dishare\file_foto.jpg")
End Sub

Permasalah yang sering muncul menggunakan cara ini adalah, folder yang dishare gagal/tidak dapat diakses dari komputer lain dan tentu saja kode diatas juga akan gagal menampilkan gambarnya.

Jika Anda menemukan kasus seperti ini, mungkin langkah-langkah berikut bisa di coba :

  1. Mengaktifkan File and Printer Sharing
  2. Mengaktifkan pilihan Use simple file sharing pada setting folder option
  3. Menyamakan user dan password komputer server dan klien
  4. Menonaktifkan windows firewall

Jika langkah-langkah diatas masih gagal juga, mungkin kita akan coba cara yang terakhir.

3. Memanfaatkan service FTP

Untuk mengaktifkan service FTP di windows (untuk contoh disini saya menggunakan windows xp sp2) kita bisa menggunakan Internet Information Services (IIS) atau memanfaatkan tool gratis yg banyak beredar dipasaran seperti FileZilla Server dan di artikel ini saya menggunakan FileZilla Server. Oke langsung saja download filenya diSINI.

Berikut langkah-langkah instalasi plus konfigurasinya.

1. Instalasi

Jalankan file FileZilla Server yang sudah Anda download kemudian tinggal ikuti saja wizard instalasinya.

2. Menambahkan group user

Disini kita akan menambahkan group dan user yang diberi izin untuk mengakses folder tertentu, dalam hal ini folder foto.

Setelah proses instalasi diatas selesai kita langsung dihadapkan pada form login.

Isikan password Administrator misalkan “admin”, setelah itu akan tampil form utama FileZilla Server Interface.

kemudian klik tombol toolber user group, setelah itu akan tampil dialog untuk menambahkan user group

isikan nama group misal “akses_foto”  seperti gambar diatas, selanjutkan kita akan menentukan folder yang akan diakses dengan mengaktifkan node Shared folders

3. Menambahkan user

kemudian klik tombol toolbar user accounts, setelah itu akan tampil dialog untuk menambahkan user.

kemudian jangan lupa isikan password usernya, misal “rahasia”

Langkah-langkah untuk menambahkan group dan user cukup sampai disini.

4. Mendaftarkan port FTP

Agar port FTP (defaultnya 21) bisa diakses komputer lain, maka port tersebut harus kita daftarkan di windows firewall. Jika windows firewallnya dinonaktifkan maka langkah-langkah ini bisa kita abaikan.

Berikut langkah-langkah mendaftarkan port FTP.

1. Masuk ke Control Panel -> Windows Firewall, kemudian aktifkan tab Exceptions

2. Klik tombol Add Port, kemudian isikan informasi Name dan Port number

3. Jika berhasil pada list Programs and Services akan ditampilkan port yang baru kita daftarkan

5. Ngetes service FTP via command prompt

Setelah semua proses selesai mulai dari instalasi, konfigurasi group dan user yang diakhiri dengan mendaftarkan port FTP, saatnya kita mencoba untuk mengetes service FTPnya dari komputer lain.

Dengan asumsi ip server adalah “192.168.0.6″, kita masuk ke dos prompt kemudian ketik ftp 192.168.0.6

Jika konfigurasi service FTP yang kita lakukan dilangkah-langkah sebelumnya benar, kita akan diminta untuk memasukkan username dan password dan jika berhasil prompt akan berganti menjadi ftp> yang menandakan bahwa username dan password kita benar.

Untuk testing lebih lanjut, kita akan coba menampilkan daftar direktori dan file dengan printah ls.

terakhir untuk keluar dari prompt ftp ketik printah bye.

Sampe disini semua persiapan kita sudah selesai dan saatnya mengeluarkan jurus pamungkas :D untuk mengakses service FTP dari vb.

Ada banyak referensi salah satunya bisa langsung merujuk ke sumber Microsoft atau yang paling gampang dengan memanfaatkan kelas FTPClass, untuk contoh disini saya akan menggunakan kelas FTPClass.

Berikut contoh penggunaan kelas tersebut.

1. Menampilkan daftar direktori dan file

Private Sub cmdDaftarFile_Click()
    Dim objFTP      As FTPClass
    Dim objFTPFile  As FTPFileClass

    Dim serverName  As String
    Dim userName    As String
    Dim password    As String

    serverName = "192.168.0.6"
    userName = "k4m4r82"
    password = "rahasia"

    Set objFTP = New FTPClass
    If objFTP.OpenFTP(serverName, userName, password) Then
        If objFTP.SetCurrentFolder("/") Then
            For Each objFTPFile In objFTP.Files
                List1.AddItem objFTPFile.FileName
            Next
        End If
        objFTP.CloseFTP

    Else
        'TODO : tampilkan pesan gagal membuka port FTP
    End If
    Set objFTP = Nothing
End Sub

2. Menampilkan file gambar sesuai dengan pembahasan inti artikel kita kali ini

Private Sub cmdLoadFoto_Click()
    Dim objFTP      As FTPClass

    Dim serverName  As String
    Dim userName    As String
    Dim password    As String
    Dim foto        As String

    serverName = "192.168.0.6"
    userName = "k4m4r82"
    password = "rahasia"

    foto = "02024112.jpg" 'contoh nama file gambar yang ingin ditampilkan

    Set objFTP = New FTPClass
    If objFTP.OpenFTP(serverName, userName, password) Then
        If objFTP.SetCurrentFolder("/") Then
            If objFTP.FileExists(foto) Then 'cek dulu file gambarnya dan jika ada...
                Call objFTP.GetFile(foto, App.Path & "\" & foto, True) 'download file gambarnya ke komputer lokal
                picSiswa.Picture = LoadPicture(App.Path & "\" & foto) 'baru ditampilkan
            End If
        End If
        objFTP.CloseFTP

    Else
        'TODO : tampilkan pesan gagal membuka port FTP
    End If
    Set objFTP = Nothing
End Sub

Selamat MENCOBA :)

About these ads
  1. September 22, 2010 at 11:17 am | #1

    Admin: Terima kasih atas tutor yang sangat bermanfaat ini! Tetap semangat dan maju terus!!!

    Salam
    delphifocus

    • September 23, 2010 at 12:18 am | #2

      Tq om udah mampir lagi :smile:

  2. October 9, 2010 at 7:25 am | #3

    wah keren keren., sampe bingung bacanya aKu.,., gagagagagag,.,.,.
    dah aku pasang linknya loh mas Rudi., ^^

  3. October 15, 2010 at 6:58 am | #5

    wedew.. saya kira bikin remote desktop kyk om sanosuke.. hehehehe
    salah sangka rupanya..
    BTW mantab om tutornya :D

    • October 16, 2010 at 1:22 am | #6

      remote desktopnya om sanosuke emg udah jadi ya? kayaxnya terakhir kontax masih pusing gitu :lol:

  4. October 16, 2010 at 2:21 am | #7

    wah saya jg kurang tau om hehehe

  5. oase39
    October 29, 2010 at 4:52 am | #8

    Makasih bang admin atas tutornya, tutorialnya keren :D

  6. November 14, 2010 at 1:54 am | #10

    mas, kenapa di komputerku tidak bisa ya, sudah saya setting persis seperti tutorial diatas, saya mencoba dengan 1pc dan 1 notebook acer, di pc sebagai server dan notebook nya sebagai client,
    keterangan:
    ip pc 192.168.0.2
    ip notebook 192.168.0.1
    dari notebook saya ketik : ftp 192.168.0.2
    pesan yang muncul = >ftp: connect Unknown error number
    tapi kalau saya ping 192.168.0.2 connect
    pada firewall nya juga sudah saya setting

    kemungkinan apa ya mas? mohon bantuannya :)

  7. November 14, 2010 at 4:09 am | #11

    kayaxnya error “ftp: connect Unknown error number” udah banyak yg bahas diinternet, atw om coba dulu testing ftp lokalan.

  8. November 27, 2010 at 12:49 am | #12

    Makasaih om infonya….kebetulan mau buat scedhuler download and upload ke ftp nich

  9. deni
    January 13, 2011 at 2:26 am | #14

    Boss, dikomputerku ko ga bisa log-in ya….padahal connect ke ftpnya sudah OK,settingannya juga sama persis dengan apa yang sudah Boss jelaskan.
    tapi pas coba di CMD saya masukin user ma pass nya ga mo log-in.padahal user ma pass nya sudah sama.itu kira-kira knapa ya..dan bagaimana solusinya?
    aku pasang fizilla ini di windows 2003 server.

    • January 13, 2011 at 2:38 am | #15

      Loh si om katanya udah connect ke ftp tapi enggak bisa login ? Trus taunya connect dari mana ?

      coba conect ke localnya dulu om, bari dr komputer laen.

  10. deni
    January 13, 2011 at 4:06 am | #16

    Maksudku gini lo boss, pas di CMD itu kan aku ketikin

    ftp ip address
    dan muncul connect to ip address
    terus minta diketikkan username,aku masukkan usernamenya…kemudian enter
    terus minta password aku masukkan juga …nah pas aku enter
    katanya error 530 User (myUserName) cannot log-in .
    login failed.

    padahal username sama passwordnya sudah sama,sudah saya cek berulang-ulang create user baru lagi hasilnya tetep sama, termasuk yg boss saranin coba connect dari kompi lain…dia minta username ma password tapi ketika asku masukkin hasilnya selalu sama login-failed.nah itu gmn boss…tolong solusinya?

    • January 13, 2011 at 5:23 am | #17

      oke om berarti instalasi FileZilla Server sukses, mungkin yg bermasalah pada saat pembuatan group dan usernya, jd klo om memang sempat coba emailkan capture pada saat pembuatan group dan user plus tes connect via cmdnya, seperti langkah2x sy diatas.

  11. hari
    July 26, 2011 at 12:21 am | #18

    Mz Admin Tanya,, klo prosesnya gini, tampilkan gambar by webcam di picture Box trus simpannya di drive komputer lain via ftp codenya gmana y bingung??

    • July 26, 2011 at 9:20 am | #19

      Klo nangkep gambar yg di webcam bisa langsung cek disini om, nanti hasil capturenya disimpan di lokalan trus tinggal diupload via ftp susuai petunjuk diatas.

  12. hari
    July 26, 2011 at 12:42 pm | #20

    klo nangkap gbr via webcam sdah bisa om,,tpi pada saat save pengennya gambar langsung msuk drive server g usah simpan di lokal dulu mohon bantuannya….sebelumnya thanx y om atas jawabanya

    • July 26, 2011 at 2:21 pm | #21

      Class ftp diatas enggak support om yg seperti itu, soalnya method PutFile yg digunakan untuk mengupload file membutuhkan parameter lokasi file.

      Kan filenya setelah sukses diupload langsung dihapus aja om

  13. hari
    July 27, 2011 at 12:43 am | #22

    kalo untuk coding uploadnya di bagian mana to om,,ak agak bingung soalnya,,y maklum masih belajar kemampuan analisa masih lemah…atas jawabannya thanx lgi y om moga2 dapat berguna buat umat buat sya dan temen2 lain yang pnya kasus yg sma…

    • July 27, 2011 at 3:03 am | #23

      Coba gini om :

      Dim objFTP As FTPClass
      
      Set objFTP = New FTPClass
      If objFTP.OpenFTP(SERVER, USER_NAME, USER_PASS) Then
          If objFTP.SetCurrentFolder("/") Then
          
              If objFTP.PutFile("LOKASI_FILE\NAMA_FILE", "NAMA_FILE", True) Then
                      
                  MsgBox "upload sukses"
                  
              End If
      
          End If
          objFTP.CloseFTP
      End If
      Set objFTP = Nothing
      
  14. hari
    July 28, 2011 at 12:39 am | #24

    maz admin,,sdah sya cba-cba tetep g bisa jew, g bisa upload file dari webcam di picture box ke folder FTP,..ini coding saya tolong dikoreksi mz newbie ni :

    Private Sub cmdUpload_Click()
    Dim objFTP As FTPClass

    Dim ServerName As String
    Dim Username As String
    Dim Password As String
    Dim foto As String

    ServerName = “127.0.0.1″
    Username = “hari”
    Password = “amboy”

    foto = Text.Text + “.jpg” ‘nama gambar yang di upload

    Set objFTP = New FTPClass
    If objFTP.OpenFTP(ServerName, Username, Password) Then
    If objFTP.SetCurrentFolder(“/”) Then

    If objFTP.PutFile(“FTP\picSiswa”, “picSiswa”, True) Then

    MsgBox “upload sukses”

    End If

    End If
    objFTP.CloseFTP
    End If
    Set objFTP = Nothing

    End Sub

  15. hari
    July 28, 2011 at 12:41 am | #25

    oh iya sebelumnya thanx y om

    • July 28, 2011 at 2:05 pm | #26

      Untuk memudahkan mencari kesalahannya om, mendingan om test dulu upload sembarang file klo enggak bisa berarti ada yg enggak benar di settingan di FTPnya

  16. hari
    July 30, 2011 at 11:30 am | #27

    klo sya cba pke filezilla client server dah OK tu om,,n tk pke sourcecode yang diatas juga dah bsa n maknyus,,tpi saya agak bingung cara simpan gambar dr webcam via ftp,, jadi maunya sich dari picturebox trus gamabr capture dari webcam namanya sesuai dengan nama yang kita berikan di texbox gtu om,,kira2 bsa g y…klo mang ftpnya g support ya mau diapain lgi

    • July 30, 2011 at 1:57 pm | #28

      Makanya jadi programmer itu harus banyak solusi om, untuk nyimpan gambar langsung dari webcam kan memang enggak bisa (CMIIW).

      Sekarang pertanyaannya waktu proses capture sedang berlangsung, hasil capturenya om tampilkan dimana ??? PictureBox atau Image ???

      Sy asumsikan om menampilkannya ke objek PictureBox, nah waktu proses capturenya om stop hasil gambarnya kan masih nyantol di PictureBoxnya, jadi om tinggal simpan aja gambar yg nyantol di PictureBox ke dalam bentuk file pake perintah ini :

      Call SavePicture(Picture1.Picture, "c:\hasil_capture.jpg")
      

      Untuk kode di event tombol stopnya lebih kurang seperti ini :

      Private Sub cmdStop_Click()
          ' TODO : perintah untuk menyetop proses capture
          
          ' simpan hasil capture ke dalam bentuk file
          ' dengan asumsi capture ditampilkan ke objek PictureBox
          Call SavePicture(Picture1.Picture, "c:\hasil_capture.jpg")
          
          ' nah dari sini baru bisa dilakukan proses upload ke FTP SERVER
          ' karena file gambarnya sudah ada
          Dim objFTP As FTPClass
      
          Set objFTP = New FTPClass
          If objFTP.OpenFTP(SERVER, USER_NAME, USER_PASS) Then
              If objFTP.SetCurrentFolder("/") Then    
                  If objFTP.PutFile("c:\hasil_capture.jpg", "hasil_capture.jpg", True) Then    
                      MsgBox "upload sukses"  
                  End If    
              End If
              objFTP.CloseFTP
          End If
          Set objFTP = Nothing
      
      End Sub
      

      Gimana om simple bukan ?

  17. hari
    July 31, 2011 at 1:23 pm | #29

    ok om,,siap sdah berhasl qo…trus berkarya n met Menunaikan Ibadah Puasa,,..hidup programer vb indonesia :)

  18. hari
    July 31, 2011 at 1:25 pm | #30

    ok sdah bisa qo om,,trus berkarya n met Menunaikan Ibadah Puasa..,,hidup programer vb indonesia

  19. October 10, 2011 at 2:10 pm | #32

    mantab om….(^_^)

  20. snowgun
    February 23, 2012 at 3:38 pm | #34

    Om Amdin,…
    saya mau tanya, kenapa ukuran file yang ditranser menjadi lebih besar dari ukuran file sebelumnya.? ukuran file sebelum dtransfer 1,37 MB, tetapi setelah ditransfer ukuran file nya lebih dari 1GB. Mohon pencerahan om Admin…

    • February 23, 2012 at 3:52 pm | #35

      Ah yg benar aja om, sy udah sering make class ftp diatas enggak pernah ada masalah

  21. snowgun
    February 24, 2012 at 10:59 am | #36

    iya om..
    lalu untuk menghapus nya memakai ftp class gmn om.?

    • February 24, 2012 at 6:55 pm | #37

      Kan tinggal manggil method DeleteFilenya om

  22. snowgun
    February 27, 2012 at 10:00 am | #38

    ok om..
    thx atas info nya..

  23. Mamet
    March 15, 2012 at 1:55 pm | #40

    om admin, ada contoh yg lebih spesifik g untuk proses update dan delete nya..
    mohon pencerahan nya om.
    msh new bie nh
    thx.

    • March 15, 2012 at 7:59 pm | #41

      Klo update enggak ada om :D, jadi bisa diwakili dengan 2 proses yaitu Delete dan Put

      Contoh pemakaianya sama kode diatas tinggal ganti aja nama methodnya, makanya dicoba dulu ada masalah baru bertanya.

  24. mamet
    March 22, 2012 at 2:57 pm | #42

    Thx om admin..
    masalah sudah terpecahkan…

  25. madhe
    May 31, 2012 at 12:11 pm | #44

    Om Untuk Uploadnya Nama filenya koq tidak bisa sama dengan apa yang kita kirim yah, namanya jadi “True” (tanpa extension).

  26. madhe
    May 31, 2012 at 1:38 pm | #46

    Spt ini om

    Private Sub Command1_Click()
    Dim objFTP As FTPClass
    Dim upfoto As String

    Dim ServerName As String
    Dim Username As String
    Dim Password As String
    ‘Dim foto As String

    ServerName = “192.168.30.6″
    Username = “madhe”
    Password = “madhe”

    upfoto = “b.jpg”

    Set objFTP = New FTPClass
    If objFTP.OpenFTP(ServerName, Username, Password) Then
    If objFTP.SetCurrentFolder(“/”) Then

    ‘If objFTP.PutFile(“LOKASI_FILE\NAMA_FILE”, “NAMA_FILE”, True) Then
    If objFTP.PutFile(App.Path & “\” & upfoto, True) Then

    MsgBox “upload sukses”

    End If

    End If
    objFTP.CloseFTP
    End If
    Set objFTP = Nothing

    End Sub

    thanks om sdh di respond sebelumnya

    • May 31, 2012 at 2:51 pm | #47

      Coba seperti ini om :

      If objFTP.PutFile(App.Path & "\" & upfoto, upfoto, True) Then
      
  27. madhe
    May 31, 2012 at 3:04 pm | #48

    ok Om Terima kasih sudah bisa, satu lagi om kalau untuk vb.net nya bagaimana yah, saya sudah coba convert ke vb.net tapi banyak yang error mungkin om ada petunjuk untuk vb.net nya. sekali lagi terima kasih smoga om di permudahkan segalanya. Aminnnn

    • May 31, 2012 at 3:29 pm | #49

      Amin :)

      Klo di .NET sy biasanya menggunakan FTP Library, walaupun contohnya menggunakan C# aslinya tetap bisa diimplementasikan utk VB .NET

  28. eko
    June 29, 2012 at 1:23 pm | #50

    mz klo mau simpan/send data via ftp ke server, pakai vb seperti diatas soucodenya bgaimana??thanx sblmnya

    • June 30, 2012 at 8:02 pm | #51

      Datanya dalam bentuk apa dulu nih ? Klo file ya sama seperti yg sudah sy jelaskan di atas.

      • eko
        July 2, 2012 at 6:29 am | #52

        datanya dalam 1 folder om…thanx seblmnya
        atas jawabannya

        • July 6, 2012 at 1:21 pm | #53

          Klo datanya ada didalam folder, kan berarti dalam bentuk file berarti caranya sama seperti yg sy jelaskan diatas.

          Pada contoh diataskan kan sy membahas bagaimana mengirim file gambar ke server.

  29. Dino
    June 30, 2012 at 3:40 pm | #54

    omm saya pengen simpan gambar pada image1 ini program
    http://www.ziddu.com/download/19801744/SimpanGambardariclick.rar.html
    saya ingin file gambar yang dibuka terakhir sebelum form di stop tersimpan , sehingga nanti pas di play atau run gamabar itu muncul lagi gimana ya omm,,
    mohon di bantu, terima kasih

  30. eko
    June 30, 2012 at 3:54 pm | #55

    Adminnya kemana ya ??

    • luky
      June 30, 2012 at 5:08 pm | #56

      Lagi Week end omm , kan musim liburan sekolah heee,,
      ya beruntungnya om Rudi lagi libur ditunggu banyk orang . Semoga menjadi orang yang paling bermanfaat bagi orang lain, karena manusia yang paling mulia di bumi adalah yang paling bermanfaat bagi sesamanya ^_^

    • June 30, 2012 at 8:48 pm | #58

      Ini baru kembali dari dunia nyata om :D

  31. Dino
    June 30, 2012 at 9:04 pm | #59

    saya pengen simpan gambar pada image1 ini program
    http://www.ziddu.com/download/19801744/SimpanGambardariclick.rar.html
    saya ingin file gambar yang dibuka terakhir sebelum form di stop tersimpan , sehingga nanti pas di play atau run gamabar itu muncul lagi gimana ya omm,,
    mohon di bantu, terima kasih

    • June 30, 2012 at 9:50 pm | #60

      Untuk menyimpan lokasi gambar bisa menggunakan fungsi SaveSetting

      Private Sub Image1_Click()
          With CommonDialog1
              .DialogTitle = "Pilih foto yang mau di insert"
              .ShowOpen
              Image1.Picture = LoadPicture(.FileName)
              
              ' simpan lokasi gambar
              Call SaveSetting("MyApp", "Setting", "LokasiGambar", .FileName)
          End With
      End Sub
      

      Sebelum gambar terakhir kita tampilkan, dicek dulu file gambarnya ada atw tidak dg menambahkan sebuah fungsi misal dg nama fileExists

      Private Function fileExists(strNamaFile As String) As Boolean
          On Error GoTo errHandle
          
          If Not (Len(strNamaFile) > 0) Then fileExists = False: Exit Function
          
          If Dir$(strNamaFile, vbNormal) = "" Then
              fileExists = False
          Else
              fileExists = True
          End If
          
          Exit Function
      errHandle:
          fileExists = False
      End Function
      

      Untuk mendapatkan informasi yg disimpan menggunakan fungsi SaveSetting kita bisa menggunakan fungsi GetSetting.

      Private Sub Form_Load()
          Dim gambarTerakhir As String
          
          ' ambil lokasi gambar terakhir
          gambarTerakhir = GetSetting("MyApp", "Setting", "LokasiGambar", "")
          
          ' cek file gambar
          If fileExists(gambarTerakhir) Then Image1.Picture = LoadPicture(gambarTerakhir)
      End Sub
      
      • Dino
        June 30, 2012 at 10:07 pm | #61

        Thank You,, omm
        kalo ndak salah ini kan disimpan pada registry windows , apa nantinya ndak menimbulkan cras atau mempengarui kesetabilan sistem atau bahkan makan penyimpanan hardisk ?? maaf banyak nanya masih pemula omm

        • July 1, 2012 at 11:27 am | #62

          Yuph benar sekali om, fungsi SaveSetting dan GetSetting itu fungsi bawaan VB 6 untuk menyimpan informasi ke registry windows.

          Namanya jg fungsi bawaan om, jadi tentu saja aman.

          • Dino
            July 1, 2012 at 1:54 pm | #63

            Ok matur ThankYu omm,, salam kenal

  32. November 6, 2012 at 12:06 am | #65

    Untuk upload sudah sukses. Tapi ketika ada nama file yang sama kenapa justru di delete bukannya di-overwrite?

  1. April 16, 2014 at 9:13 am | #1

Leave a Reply

Fill in your details below or click an icon to log in:

WordPress.com Logo

You are commenting using your WordPress.com account. Log Out / Change )

Twitter picture

You are commenting using your Twitter account. Log Out / Change )

Facebook photo

You are commenting using your Facebook account. Log Out / Change )

Google+ photo

You are commenting using your Google+ account. Log Out / Change )

Connecting to %s

%d bloggers like this: