Home > Visual Basic > Input data via grid

Input data via grid

May 12, 2012

Sudah lama enggak posting tentang Visual Basic 6 jadi kangen juga😀.

Kali ini kita akan membahas bagaimana mudahnya melakukan input data langsung di grid menggunakan komponen VSFlexGrid.

VSFlexGrid sudah menyediakan beberapa method dan event yang mempermudah kita untuk melakukan hal ini, kita lihat screenshotnya.

Berikut beberapa fitur yang akan kita bahas :

1. Validasi

Pada sample program di atas kita akan menambahkan beberapa validasi input seperti konversi ke huruf besar untuk kolom NAMA BARANG dan validasi input angka untuk kolom STOK dan HARGA JUAL. Kedua fitur ini membutuhkan fungsi berikut :

Private Function convertToUpper(ByVal keyAscii As Integer) As Integer
    convertToUpper = Asc(UCase$(Chr$(keyAscii)))
End Function

Private Function numericOnly(ByVal keyAscii As Integer) As Integer
    Dim strValid As String

    On Error GoTo errHandle

    strValid = "0123456789."
    If InStr(strValid, Chr(keyAscii)) = 0 And Not (keyAscii = vbKeyBack) Then
        numericOnly = 0
    Else
        numericOnly = keyAscii
    End If

    Exit Function
errHandle:
    numericOnly = 0
End Function

Selanjutnya fungsi diatas tinggal dipanggil di event KeyPressEdit dari komponen VSFlexGrid.

Private Sub Grid1_KeyPressEdit(ByVal Row As Long, ByVal Col As Long, keyAscii As Integer)
    If keyAscii = vbKeyReturn Then
        Call nextFocus
    End If

    Select Case Col
        Case 0 ' kode barang
        Case 1 ' nama barang
            keyAscii = convertToUpper(keyAscii)
        Case 2, 3 ' stok dan harga
            keyAscii = numericOnly(keyAscii)
    End Select
End Sub

2. Focus dan Lostfocus backcolor

Sesuai nama fiturnya cell grid akan berubah warna ketika cursor mouse aktif pada cell.

Private Sub Grid1_StartEdit(ByVal Row As Long, ByVal Col As Long, Cancel As Boolean)
    If Col = 3 Then ' harga jual
        Grid1.TextMatrix(Row, Col) = Replace(Grid1.TextMatrix(Row, Col), ",", "")
    End If

    Grid1.CellBackColor = &HC0FFFF ' warna kuning
End Sub

Private Sub Grid1_AfterEdit(ByVal Row As Long, ByVal Col As Long)
    If Col = 3 Then ' harga jual
        If IsNumeric(Grid1.TextMatrix(Row, Col)) Then
            Grid1.TextMatrix(Row, Col) = FormatNumber(Grid1.TextMatrix(Row, Col), 0)
        End If
    End If
    Grid1.CellBackColor = vbDefault
End Sub

Terakhir agar mode edit cellnya aktif pada saat cursor mouse aktif tinggal panggil method EditCell di event Click dan EnterCell

Private Sub Grid1_Click()
    Grid1.EditCell
End Sub

Private Sub Grid1_EnterCell()
    Grid1.EditCell
End Sub

Selamat MENCOBA🙂

  1. May 15, 2012 at 9:59 am

    om kalau coding untuk total gimana om, misalkan dari kolom “harga jual”, ada label atau textbox dibawah vsflexgrd yang isinya total/jumlah dari kolom “harga jual”, mohon pencerahanya

    • May 18, 2012 at 1:52 pm

      Tambahkan fungsi berikut :

      Private Function sumGrid(ByVal grid As VSFlexGrid, ByVal kolom As Integer) As Long
          Dim i       As Integer
          Dim harga   As String
          Dim total   As Long
          
          For i = 1 To grid.Rows - 1
              harga = Replace(grid.TextMatrix(i, kolom), ",", "")
              If Len(harga) = 0 Then harga = "0"
              
              If IsNumeric(harga) Then total = total + CLng(harga)
          Next i
          
          sumGrid = total
      End Function
      

      Kemudian tinggal panggil dievent AfterEdit

      Private Sub Grid1_AfterEdit(ByVal Row As Long, ByVal Col As Long)
          If Col = 3 Then ' harga jual
              If IsNumeric(Grid1.TextMatrix(Row, Col)) Then
                  Grid1.TextMatrix(Row, Col) = FormatNumber(Grid1.TextMatrix(Row, Col), 0)
                  
                  ' hitung totalnya disini
                  lblTotal.Caption = sumGrid(Grid1, Col)
              End If
          End If
          Grid1.CellBackColor = vbDefault
      End Sub
      
  2. aya
    May 15, 2012 at 12:26 pm

    salam kenal, mo nanya neh gimana caranya klo kita mo konversi tanggal dari inputan pada datagrid — misalnya 01012012 ke format 01-01-2012 — trims

    • May 18, 2012 at 1:57 pm

      Datagrid ya? Udah lupa ey😀

  3. May 16, 2012 at 8:58 am

    misi om, mau nanya lagi nih… kalo cara ngambil data dari tabel lain trus di kasih ke tabel yg baru gimana ya??

    • May 19, 2012 at 8:44 am

      Coba sql ini om :

      INSERT INTO tabel_a SELECT field_1, field_2, field_n FROM tabel_b
      

      Field yg ada di tabel_a harus sama dengan jumlah field yg muncul pada pernyataan SELECT

      • May 21, 2012 at 5:26 pm

        gini om, contohnya kaya yg di smart library itu. antara tabel master buku sama tabel peminjaman, gitu lho om… yg di peminjaman kan cuma tercantum kode bukunya aja.. nha itu apakah sama? pake select kya yg di atas itu juga?? maaf banyak nanya om, tp mkasih atas bimbingannya…

  4. May 18, 2012 at 9:36 am

    Wah akhirnya om admin posting juga tentang ini, thaks om admin ….🙂

    om gimana ne mau validasi kolom ya, misalkan kolom kode barang ya gak bisa diedit tp untuk kolom yang laen ya bisa, ,,

    • May 19, 2012 at 9:23 am

      Validasinya ditambahkan di event KeyPressEdit, select kolom 0 (kode barang) trus set nilai keyAscii = 0

      Private Sub Grid1_KeyPressEdit(ByVal Row As Long, ByVal Col As Long, keyAscii As Integer)
          If keyAscii = vbKeyReturn Then
              Call nextFocus
          End If
          
          Select Case Col
              Case 0 ' kode barang
                  keyAscii = 0 'disable input keyboard
                  
              Case 1 ' nama barang
                  keyAscii = convertToUpper(keyAscii)
              Case 2, 3 ' stok dan harga
                  keyAscii = numericOnly(keyAscii)
          End Select
      End Sub
      
      • May 21, 2012 at 1:06 pm

        OK om thaks ya …🙂

  5. May 20, 2012 at 3:58 pm

    om kalau inputnya tombol tertentu gimana om listingnya, misalkan hanya bisa di input huruf A dan B saja. mksi

    • May 26, 2012 at 10:03 am

      Tinggal copy om fungsi numericOnly diatas misal diganti menjadi letterOnly trus variabel strValidnya diisi “AB”, selanjutnya tinggal panggil seperti memanggil fungsi numericOnly

  6. rickz
    May 21, 2012 at 3:05 pm

    Klo untuk menyimpan ke databasenya gmana tuh om??

    • May 26, 2012 at 10:04 am

      Memmm g mana ya ?😀

  7. May 27, 2012 at 5:11 pm

    om kalau nginput KODE BARANG -nya menggunakan alat seperti disupermarket (barcode scanner) itu , codingnya gimana om, mohon pencerahnaya.

    • May 27, 2012 at 7:50 pm

      Klo skrg kan barcode readernya rata2x udah pake usb semua om, jadi tinggal colokin aja dan enggak perlu kode2x khusus utk baca hasil barcodenya.

      Intinya barcode reader itu hanya sebagai pengganti input keyboard.

  8. Sholihamizic
    May 28, 2012 at 4:37 pm

    Mau nanya om, saya kan bikin aplikasi absensi barcode … pas nginput kode barcode yang pertama maunya ke isi di kolom masuk trus input ke dua ke isi di kolom keluar…. tu bikinnya gmn ya om…. pusing ni, padahal klo itu dah jadi siap demo skripsi ni om… mohon pencerahannya…

    • May 29, 2012 at 8:50 am

      Maksudnya kolom apa nih om ? Kolom di flexgridnya atw kolom/field di database ?

  9. May 30, 2012 at 11:03 am

    om admin ada contohnya gak sourcode sederhana untuk operasi record ya (tambah,simpan,edit,hapus,cari) pake VSFlexGrid dan convert dari VSFlexGrid ke Excell tapi yang sederahan aja om, soal ya liat sourcode Aplikasi Smart libry school itu ribet bgt pake class, hehehe kurang paham ,,,,,

    • May 31, 2012 at 10:02 am

      Yah yg namanya belajar itu memang butuh proses om😀

  10. ruben
    June 6, 2012 at 7:46 am

    Om kalo mau mengunci baris2 dibawahnya kalu baris diatas belum terisi bagaimana om?

    • June 6, 2012 at 8:48 am

      Oke dg asumsi semua kolom di atasnya harus terisi, coba tambahkan fungsi berikut :

      Private Function isValidCell(ByVal grid As VSFlexGrid) As Boolean
          Dim currentRow  As Long
          Dim i           As Integer
          
          currentRow = grid.Row
          
          isValidCell = True
          If currentRow > 1 Then
              For i = 0 To grid.Cols - 1
                  ' cek apakah ada kolom yg belum diisi ?
                  If Len(grid.TextMatrix(currentRow - 1, i)) = 0 Then
                      isValidCell = False
                      Exit For
                  End If
              Next i
          End If
      End Function
      

      Dilanjutkan dengan merevisi event Grid1_KeyPressEdit

      Private Sub Grid1_KeyPressEdit(ByVal Row As Long, ByVal Col As Long, keyAscii As Integer)
          If keyAscii = vbKeyReturn Then
              Call nextFocus
          End If
          
          ' panggil fungsi isValidCell disini
          If isValidCell(Grid1) Then
              Select Case Col
                  Case 0 ' kode barang
                      'keyAscii = 0
                      
                  Case 1 ' nama barang
                      keyAscii = convertToUpper(keyAscii)
                      
                  Case 2, 3 ' stok dan harga
                      keyAscii = numericOnly(keyAscii)
              End Select
          
          Else
              keyAscii = 0
          End If
      End Sub
      
      • ruben
        July 5, 2012 at 8:27 am

        let me try, trims om

        • ruben
          July 5, 2012 at 12:21 pm

          Top Markotop .codenya . .

  11. June 30, 2012 at 10:32 am

    makasih infonya kang. kalo mau gabungin colum gimana ya..? matur nuwon

    • June 30, 2012 at 8:43 pm

      Seperti ini maksudnya ? Klo iya coba kode berikut :

      Private Sub Form_Load()    
          With VSFlexGrid1
              .FixedRows = 2
              
              .TextMatrix(0, 0) = "Nilai"
              .TextMatrix(0, 1) = "Nilai"
              .MergeCells = flexMergeFixedOnly
              .MergeRow(0) = True
              
              .FixedAlignment(0) = flexAlignCenterCenter
              
              .TextMatrix(1, 0) = "Huruf"
              .TextMatrix(1, 1) = "Angka"
          End With
      End Sub
      
  12. ruben
    July 5, 2012 at 10:51 am

    makasih contoh codenya.
    bisa gak kita nambahin nomor baris di grid ini? caranya gimana om?

    • July 22, 2012 at 6:30 pm

      Silahkan dicoba dulu😀

  13. ruben
    July 5, 2012 at 10:59 am

    supaya editing text lebih mudah, saya coba untuk binding textbox ke kolom 1 kok gak bisa ya?
    cara untuk mengikatkan textbox ke suatu kolom bgimana ya om?

    • July 22, 2012 at 6:32 pm

      Kayaxnya cukup seperti ini :

      VSFlexGrid1.TextMatrix(baris, kolom) = Text1.Text
      

      Untuk baris bisa didapatkan dari perintah VSFlexGrid1.Row

  14. Dwi
    July 16, 2012 at 2:46 pm

    om cara ngambil data yang ada di Vs Gird ke Active Report2 gimana yak
    tolong dbantu yak

    • July 21, 2012 at 9:33 am

      Untuk membaca nilai yg ada di Vs Grid, gunakan perintah berikut :

      MsgBox VSFlexGrid1.TextMatrix(baris, kolom)
      

      Trus tinggal gabungkan dengan postingan sy yg disini.

  15. August 4, 2012 at 12:27 am

    ompimpa kalo di kolom tabel barang pengen kita tambahin button buat lookup bs gak ya ?? kaya model xtableedit gt. tengkyu🙂

    • August 4, 2012 at 10:46 am

      Coba testing seperti ini dulu :

      Private Sub Form_Load()
          VSFlexGrid1.Editable = flexEDKbd
          VSFlexGrid1.ColComboList(2) = "#1;Pilihan #1|#2;Pilihan #2|#3;Pilihan #3"
      End Sub
      

      Pada kode di atas, ComboBox akan tampil di kolom ke tiga.

  16. AngeL
    August 15, 2012 at 1:26 pm

    Om mf nih sblmny klo oot y,, Gini om, mo minta pendapat.. Menurut om, komponen grid ap yg paling usable dpake d VB6 buat nampilin db? Jd kondisiny, grid ini hrs refresh tiap 2 menit om. Dan dgn kondisi itu ak pengenny posisi horizontal scrollbar si grid ini bisa update ke posisi sesuai pos terakhir si user menggeser HScrollbar.. U/ posisi VScrollbar ma lebar kolom grid ud bs ditanggulangi om, tggl yg HScrollbar ini om. Afwan bgt om, ak ud gugling 3 hr ttg ini tp blm ad pencerahan. Saat ini ak seringny pake True DBGrid bawaan AP*X om. Ad saran?

    • August 16, 2012 at 9:33 am

      Sy biasanya tetap make VSFlexGrid om, untuk HScrollbar mungkin bisa om coba menggunakan fungsi api berikut :

      Private Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
      
      Private Const WM_HSCROLL = &H114
      Private Const SB_BOTTOM = 7
      

      Untuk cara penggunaannya gampang :

      Private Sub Command1_Click()
          Call SendMessage(VSFlexGrid1.hWnd, WM_HSCROLL, SB_BOTTOM, 0)
      End Sub
      
      • AngeL
        August 22, 2012 at 2:53 pm

        Om, maaf lahir batin ya,, Betewe ud ak cb code-ny, tp blm bs ik om.. Abs refresh, HScrollbar gridny slalu kmbl k awl, ga k posisi terakhir ak klik. Ak cb2 lg deh om.. Thx y om,,

        • August 24, 2012 at 6:41 pm

          Sama2x om

          Pemanggilan kodenya harus urut om, panggil perintah refresh dulu baru fungsi SendMessagenya

  17. September 12, 2012 at 9:23 am

    Reblogged this on Just Code Shared.

  18. irfan
    September 23, 2012 at 1:05 am

    Tanya suhu
    Gmn cara otomatis serial.Reg vsflex8l.ocx nya?

  19. mun4war
    September 24, 2012 at 1:55 am

    bagaimana jika kita mengentri data pada jumlah stok beli … terus ketika uda input dan tekan enter maka posisi cursor pindah pada baris dibawahnya di kolom stok beli juga….

    terima kasih atas ilmunya pak

  20. mun4war
    September 24, 2012 at 12:10 pm

    terus ini lagi pak… kalau mau simpan data dari vsflexgrid ke database seperti format tabel diatas ada… kode barang, nama barang, stok dan harga jual diatas… bagaimana caranya pak….

    terima kasih atas ilmunya pak…

  21. mun4war
    September 25, 2012 at 11:51 am

    Call nextFocus kode barisnya tidak ada pak…..

  22. irma
    January 12, 2013 at 11:21 pm

    mau nanya donk..
    klo mau hitung = harga * jumlah (barang) = total
    abis total langsung ke pembayaran dan uang kembali,

    dan harganya ada di dbgrid itu gmna ya codingnya?? tpi tanpa ada command hitung

    • January 14, 2013 at 9:23 am

      Harus jelas dulu kondisi dimana proses input data barangnya selesai baru bisa fokus ke pembayaran dan uang kembali.

  23. February 4, 2013 at 1:33 am

    Halo, mas admin, mo tanya donk, bgmn caranya menampilkan waktu yg sdg berjalan di listview ato via grid? Misalnya kaya aplikasi billing kan ada waktu si client yg sedang jalan di listviewnya si server. Saya pake VB6. Mohon bantuannya, trims.

    • February 4, 2013 at 11:45 am

      Dicoba dulu om sample program berikut, mana tau bisa ngasih pencerahan.

      Gambar desain

      Demo

      Komponen yg dibutuhkan :
      1. ListView
      2. Command yang dijadikan array dengan cara mengatur properties index (0, 1, 2, dan 3)
      3. Timer yang dijadikan array dengan mengset nilai properties indexnya menjadi 0

      Private arrJamClient() As String
      
      Private Sub Command1_Click(Index As Integer)
          arrJamClient(Index) = Format(Now, "hh:mm:ss")
          Timer1(Index).Enabled = True
      End Sub
      
      Private Sub Form_Load()
          Dim i As Long
          
          Timer1(0).Enabled = False
          
          With ListView1
              .View = lvwReport
              .GridLines = True
              .ColumnHeaders.Add , , "No.", 500
              .ColumnHeaders.Add , , "Klien", 3000
              .ColumnHeaders.Add , , "Jam", 1000
      
              ' contoh data 4 klien
              For i = 1 To 4
                  .ListItems.Add , , i
                  .ListItems(i).SubItems(1) = "Client " & i
                  
                  If i > 1 Then Load Timer1(Timer1.UBound + 1)
              Next i
              
              ReDim arrJamClient(ListView1.ListItems.Count - 1)
              
          End With
      End Sub
      
      Private Sub Timer1_Timer(Index As Integer)
          arrJamClient(Index) = Format(TimeValue(arrJamClient(Index)) + TimeValue("00:00:01"), "hh:mm:ss")
          ListView1.ListItems(Index + 1).SubItems(2) = arrJamClient(Index)
      End Sub
      
  24. February 4, 2013 at 6:45 pm

    Wah berhasil, tengkyu banget mas, u are the best

    • February 5, 2013 at 1:56 pm

      Oke, senang bisa membantu🙂

  25. Chandra
    February 18, 2013 at 12:08 pm

    Mas bro numpang tanya, sy pake vb6 component VSFlexGrid sy cek kok gak ada ya, mohon pencerahannya.

    • February 19, 2013 at 8:56 am

      Komponen VSFlexGrid itu memang bukan komponen standar vb 6 jadi harus di register secara manual.

      Di contoh program di atas, sudah sy ikutsertakan komponen VSFlexGridnya.

  26. Chandra
    February 21, 2013 at 2:16 pm

    Mas Admin, mau tanya lagi nih..
    Misalnya ada 2 tabel, 1 tabel refdesk(iddesk, deskripsi) berisi 50 record, 2 tabel transaksi(iddesk,jumlah,bsu) berisi 5 record, yang ingin saya tanyakan adalah:
    bagaimana caranya menampilkan SEMUA record pd tabel refdesk disebelah kiri dan dikanannya berisi data yang ada sesuai yg ada di tabel transaksi.
    CONTOH
    ID DESK | DESKRIPSI | JUMLAH | BESAR UANG |
    001 PENSIL 40 50,000 –> data dari tabel transaksi
    002 BUKU 0 0 –> tidak ada di tabel transaksi
    003 PENA 10 100,000
    004 PENGGARIS 0 0
    005 XXX 0 0
    … … … …
    050 ZZZ 0 0

    Saya sudah coba menggunakan INNER JOIN tetapi yang tampil hanya data yang ada di kedua tabel ada saja yang tampil.
    Mohon bantuannya mas Admin, terima kasih.

    • February 21, 2013 at 2:41 pm

      Ya jelas om, soalnya klo pake INNER JOIN yang ditampilkan hanya data yang saling berpasangan di kedua tabel, trus solusinya ya pake LEFT/RIGHT JOIN, contoh :

      SELECT ...
      FROM refdesk LEFT JOIN transaksi ON refdesk.iddesk = transaksi.iddesk
      
      • Chandra
        February 21, 2013 at 4:19 pm

        Mas Admin,
        Kenapa jika query saya tambahkan kondisi untuk tabel transaksi, hasil yang di tampilkan pada grid hanya 5 record saja padahal yang saya inginkan, seluruh isi tabel refdesk tetap muncul dan isi tabel transaksi mengisi baris yang sama sesuai iddesknyang bertalian,…mohon bantuannya, terima kasih mas Admin.

        • February 21, 2013 at 4:24 pm

          Loh kan udah saya jawaba om di atas, pake LEFT/RIGHT JOIN jangan pake INNER Join.

          • Chandra
            February 21, 2013 at 7:26 pm

            maaf, maksud sy pake perintah LEFT/RIGHT JOIN itu mas Admin😀 maaf lupa menjelaskan.
            sy sudah coba pake LEFT/RIGHT JOIN tanpa kriteria, SEMUA data yang ada di tabel refdesk dan data yang ada di tabel transaksi MUNCUL seperti yang di harapkan, TETAPI jika saya tambahkan kriteria …where transaksi.tgljual=’2013-02-20′ yang ditampilkan hanya transaksi pada tanggal itu saja (ada 5 record).
            yang ingin saya tanyakan bagaimana supaya semua data yang ada pada tabel refdesk tetap muncul semua di sebelah kiri, sedangkan data yang ada di tabel transaksi mengisi di baris yang sama sesuai iddesknya…mudah2han dan yambung ya mas Admin….(Y)

            • February 22, 2013 at 8:31 am

              Klo ditambahkan klausa WHERE hasilnya memang seperti itu, solusi yg bisa dicoba sih menggunakan subquery.

              SELECT iddesk, deskripsi, 
              (SELECT SUM(jumlah) FROM transaksi WHERE iddesk = refdesk.iddesk AND tgljual=’2013-02-20′) AS Jumlah,
              (SELECT SUM(bsu) FROM transaksi WHERE iddesk = refdesk.iddesk AND tgljual=’2013-02-20′) AS Bsu
              FROM refdesk
              ORDER BY iddesk
              
  27. February 26, 2013 at 11:31 pm

    Mas mimin mau tanya donk, klo diataskan input datanya di grid, klo input datanya di listview gmn min?? trus cara add data dari listview ke database(mysql) gmn ya??

  28. anto
    March 10, 2013 at 12:54 pm

    Mas.. mohon pencerahanya,, untuk VsFlexGrid pada kolom tertentu menggunakan ColComboList.. tp saya pengenya ambil data dari Database barang… gimana ya.. code-nya..? yang saya bisa seperti ini.. ( Grid1.ColComboList(1) = “Part1|Part2|Part3|Part4” ) Terimakasih

    • March 16, 2013 at 1:11 pm

      Coba kesini om.

  29. March 21, 2013 at 10:27 am

    oya mw tanya kalo mau menghitung jumlah isi pada colom/field datagrid tp berupa text bukan angka gmn caranya semisal mau merekap absen gtu

  30. March 28, 2013 at 3:17 pm

    mau nanya ni mas , klo saya ingin menjumlahkan isi pada colom harga itu gmn ya dan hasilnya saya taruh ke textbox total

  31. agus amirudin
    May 10, 2013 at 2:44 pm

    Mas admin mau nanya nih…
    maaf saya baru belajar vb 6, untuk nampilin VSFlexGrid nya di components gimana caranya ?
    maaf saya baru mau belajar

  32. May 17, 2013 at 1:38 pm

    Assalamualaikum, Om Admin
    Saya cari2 kode untuk buat program seperti kasir alfa, jadi input data barang di gridnya langsung…, tapi tanpa terikat ke tabel apapun,
    Akhirnya ketemu Blognya Om Admin, bisa untuk referensi.
    Mhn maaf sebelumnya Om Admin, kalo dari pembahasan di atas procedure/function nextFocus kok blm ada ya, apa bisa dishare di sini
    Thx sebelumnya
    Salam

    • June 25, 2013 at 12:46 pm

      Iya om, kode lengkapnya bisa dilihat langsung di sample programnya.

  33. Yondri
    December 1, 2013 at 1:37 am

    om, maaf klo oot. tapi masih sekitar grid. yang ingin sy tanya :
    pada grid ada kolom sbb :
    kode_barang, nama_barang, satuan, harga.
    ketika ane masukin kode_barang pada kolom kode_barang, maka kolom yang lain harus terisi sesuai nama barang dan harganya yang ada pada database sesuai kode_barang-nya. jadi yang di entry hanya kode_barang saja. seperti klo kita di supermarket. mohon pencerahannya.
    terimakasih seblumnya…

  34. January 14, 2014 at 3:02 pm

    om mau tanya..
    bisa ggak ya cara memasukan textboxt ke dalam listview di vb.net,
    misalkan sya punya textbox1 mau di masukan ke listview pada kolom 4 baris 3 misalkan…
    itu bisa /tidak ya om …???
    mohon bantuannya…

  35. didik
    March 28, 2014 at 1:24 pm

    om mau tanya kalau mengisi kolom dengan data yg sma gimana ya? contoh jika ad tabel nama.nomor_id,tanggal jika nama dan nomor_id udah terisi sementara tanggal mash kosong dan akan di isi dengan datapicker gimana ya???? kalau edit satu persatu kan bisa dengan memanggil data ke textbox tp jika data yang dipanggil lebih dari satu dan kolom tanggal akan di isi secara bersama gimana om?

  36. March 28, 2014 at 1:45 pm

    Pake perulangan kali ya ?
    Pertanyaan om enggak jelas😀

  37. May 4, 2014 at 2:10 pm

    makasih om artikelnya mantab….
    ada yang mau saya tanya nih… kalo mau input untuk jam masuk dan jam keluar seperti menggunakan maskedbox gimana ya…
    mohon pencerahannya….

  1. April 16, 2014 at 9:15 am
Comments are closed.
%d bloggers like this: